home *** CD-ROM | disk | FTP | other *** search
/ The CICA Windows Explosion! / The CICA Windows Explosion! - Disc 2.iso / nt / emacssrc.zip / EMACSSRC.TAR / emacs-19.17 / lisp / cookie1.el < prev    next >
Lisp/Scheme  |  1993-07-23  |  5KB  |  146 lines
  1. ;;; cookie1.el --- retrieve random phrases from fortune cookie files
  2.  
  3. ;; Copyright (C) 1993 Free Software Foundation, Inc.
  4.  
  5. ;; Author: Eric S. Raymond <esr@snark.thyrsus.com>
  6. ;; Maintainer: FSF
  7. ;; Keywords: games
  8. ;; Created: Mon Mar 22 17:06:26 1993
  9.  
  10. ;; This file is part of GNU Emacs.
  11.  
  12. ;; GNU Emacs is free software; you can redistribute it and/or modify
  13. ;; it under the terms of the GNU General Public License as published by
  14. ;; the Free Software Foundation; either version 2, or (at your option)
  15. ;; any later version.
  16.  
  17. ;; GNU Emacs is distributed in the hope that it will be useful,
  18. ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19. ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20. ;; GNU General Public License for more details.
  21.  
  22. ;; You should have received a copy of the GNU General Public License
  23. ;; along with GNU Emacs; see the file COPYING.  If not, write to
  24. ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  25.  
  26. ;;; Commentary:
  27.  
  28. ;; Support for random cookie fetches from phrase files, used for such
  29. ;; critical applications as emulating Zippy the Pinhead and confounding
  30. ;; the NSA Trunk Trawler.
  31. ;;
  32. ;; The two entry points are `cookie' and `cookie-insert'.  The helper
  33. ;; functions `pick-random' and `shuffle-vector' may be of interest to
  34. ;; programmers.
  35. ;;
  36. ;; The code expects phrase files to be in one of two formats:
  37. ;;
  38. ;; * ITS-style LINS format (strings terminated by ASCII 0 characters,
  39. ;; leading whitespace ignored).
  40. ;;
  41. ;; * UNIX fortune file format (quotes terminated by %% on a line by itself).
  42. ;;
  43. ;; Everything up to the first delimiter is treated as a comment.  Other
  44. ;; formats could be supported by adding alternates to the regexp
  45. ;; `cookie-delimiter'.
  46. ;;
  47. ;; This code derives from Steve Strassman's 1987 spook.el package, but
  48. ;; has been generalized so that it supports multiple simultaneous
  49. ;; cookie databases and fortune files.  It is intended to be called
  50. ;; from other packages such as yow.el and spook.el.
  51. ;;
  52. ;; TO DO: teach cookie-snarf to auto-detect ITS PINS or UNIX fortune(6)
  53. ;; format and do the right thing.
  54.  
  55. ;;; Code:
  56.  
  57. ; Randomize the seed in the random number generator.
  58. (random t)
  59.  
  60. (defconst cookie-delimiter "\n%%\n\\|\0"
  61.   "Delimiter used to separate cookie file entries.")
  62.  
  63. (defvar cookie-cache (make-vector 511 0)
  64.   "Cache of cookie files that have already been snarfed.")
  65.  
  66. (defun cookie (phrase-file startmsg endmsg)
  67.   "Return a random phrase from PHRASE-FILE.  When the phrase file
  68. is read in, display STARTMSG at beginning of load, ENDMSG at end."
  69.   (let ((cookie-vector (cookie-snarf phrase-file startmsg endmsg)))
  70.     (shuffle-vector cookie-vector)
  71.     (aref cookie-vector 1)))
  72.  
  73. (defun cookie-insert (phrase-file &optional count startmsg endmsg)
  74.   "Insert random phrases from PHRASE-FILE; COUNT of them.  When the phrase file
  75. is read in, display STARTMSG at beginning of load, ENDMSG at end."
  76.   (let ((cookie-vector (cookie-snarf phrase-file startmsg endmsg)))
  77.     (shuffle-vector cookie-vector)
  78.     (let ((start (point)))
  79.       (insert ?\n)
  80.       (cookie1 (min (- (length cookie-vector) 1) (or count 1)) cookie-vector)
  81.       (insert ?\n)
  82.       (fill-region-as-paragraph start (point) nil))))
  83.  
  84. (defun cookie1 (arg cookie-vec)
  85.   "Inserts a cookie phrase ARG times."
  86.   (cond ((zerop arg) t)
  87.     (t (insert (aref cookie-vec arg))
  88.        (insert " ")
  89.        (cookie1 (1- arg) cookie-vec))))
  90.  
  91. (defun cookie-snarf (phrase-file startmsg endmsg)
  92.   "Reads in the PHRASE-FILE, returns it as a vector of strings.  Emit
  93. STARTMSG and ENDMSG before and after.  Caches the result; second and
  94. subsequent calls on the same file won't go to disk."
  95.   (let ((sym (intern-soft phrase-file cookie-cache)))
  96.     (and sym (not (equal (symbol-function sym)
  97.              (nth 5 (file-attributes phrase-file))))
  98.      (yes-or-no-p (concat phrase-file
  99.                   " has changed.  Read new contents? "))
  100.      (setq sym nil))
  101.     (if sym
  102.     (symbol-value sym)
  103.       (setq sym (intern phrase-file cookie-cache))
  104.       (message startmsg)
  105.       (save-excursion
  106.     (let ((buf (generate-new-buffer "*cookie*"))
  107.           (result nil))
  108.       (set-buffer buf)
  109.       (fset sym (nth 5 (file-attributes phrase-file)))
  110.       (insert-file-contents (expand-file-name phrase-file))
  111.       (re-search-forward cookie-delimiter)
  112.       (while (progn (skip-chars-forward " \t\n\r\f") (not (eobp)))
  113.         (let ((beg (point)))
  114.           (re-search-forward cookie-delimiter)
  115.           (setq result (cons (buffer-substring beg (1- (point)))
  116.                  result))))
  117.       (kill-buffer buf)
  118.       (message endmsg)
  119.       (set sym (apply 'vector result)))))))
  120.  
  121. (defun pick-random (n)
  122.   "Returns a random number from 0 to N-1 inclusive."
  123.   (% (logand 0777777 (random)) n))
  124.  
  125. ; Thanks to Ian G Batten <BattenIG@CS.BHAM.AC.UK>
  126. ; [of the University of Birmingham Computer Science Department]
  127. ; for the iterative version of this shuffle.
  128. ;
  129. (defun shuffle-vector (vector)
  130.   "Randomly permute the elements of VECTOR (all permutations equally likely)"
  131.   (let ((i 0)
  132.     j
  133.     temp
  134.     (len (length vector)))
  135.     (while (< i len)
  136.       (setq j (+ i (pick-random (- len i))))
  137.       (setq temp (aref vector i))
  138.       (aset vector i (aref vector j))
  139.       (aset vector j temp)
  140.       (setq i (1+ i))))
  141.   vector)
  142.  
  143. (provide 'cookie1)
  144.  
  145. ;;; cookie1.el ends here
  146.